maemo.org - Talk - gphoto2 + canon 20d + n810 = chunky super unstable eyefi

maemo.org - Talk (https://talk.maemo.org/index.php)

- OS2008 / Maemo 4 / Chinook - Diablo (https://talk.maemo.org/forumdisplay.php?f=29)

- - gphoto2 + canon 20d + n810 = chunky super unstable eyefi (https://talk.maemo.org/showthread.php?t=13868)

gphoto2 + canon 20d + n810 = chunky super unstable eyefi

I've managed to get gphoto2, perl and other assorted programs compiled for my n810 now and have been playing with the usb host stuff.

The idea I've been working on is that it's possible for a computer to view/download images from my Canon 20d camera while it's shooting. To do so, I've set the camera up in "normal mode" (rather than PTP that causes the system to pretty much shutdown aside from the connection mode) and have been trying to use gphoto2 to poll+download the camera for new images.

I've thrown together the following perl script and have used it with success on my laptop... and some with the n810. What it does is first downloads a list of all the pictures on the camera, then flags them as "seen". From then on, it will poll the camera every 5 seconds or so and downloads any new pictures it sees to the memory card. That's just the test. When it's reliable I'm thinking of geotagging the images, then using something like djpeg to resize the image then upload the picture to flickr or some other site. If I get samba working, perhaps I'll get the system to dump the pictures onto a share.

The problem I'm encountering is that most of the time, when "gphoto2 -L" is invoked, the system freezes then reboots. Is there anything I can do to figure out what's causing the reboot?

If anyone wants, I can upload a tarball of my /media/mmc1/pocket, I've managed to stuff most of the little programs that I use into there. (perl, imagemagick *slow*, vim, dcraw, jhead, mysql, apache, subversion, etc)

Code:

#!/usr/bin/perl



use strict;

use vars qw/ $CFG %SEEN /;

use Symbol;



$CFG = {

    gphoto_fpath => "/media/mmc1/pocket/bin/gphoto2",

    process_cmd => "echo Fetched {}",

    save_path => "/media/mmc1",

    poll_delay => 5,

};



main();



sub main {

# --------------------------------------------------

    my $files = camera_files();



# So that we can score the images in the right directory

    chdir $CFG->{save_path};



    while (1) {

        photos_seen_mark( $files );

        $files = camera_files();

        if ( my $not_seen = photos_seen_filter($files) ) {

            camera_file_fetch( $not_seen );

            photos_post_action( $not_seen );

        }

        sleep $CFG->{poll_delay};

    }

}



sub photos_post_action {

# --------------------------------------------------

# Execute a script or do something for each photo

# that has been fetched

#

    my $files = shift or return;

    for ( @$files ) {

        my $fpath = $CFG->{save_path}? "$CFG->{save_path}/$_->{fname}" : $_->{fname};

        my $process_cmd = $CFG->{process_cmd};

        $process_cmd =~ s/\{\}/"$fpath"/g;

        system $process_cmd;

    }

}



sub photos_seen_mark {

# --------------------------------------------------

# Mark all the photos passed via array as "seen"

#

    my $files = shift;    

    for ( @$files ) {

        $SEEN{$_->{fname}} = 1;

    }

}



sub photos_seen_filter {

# --------------------------------------------------

# Returns an array of all the photos that have 

# not been seen by the system

#

    my $files = shift;    

    my @filtered = grep {not $SEEN{$_->{fname}}} @$files or return;

    return \@filtered;

}



sub camera_file_fetch {

# --------------------------------------------------

# Fetches the files in the list passed in

#

    my $files = shift or return;

    my $range = join ",",map {$_->{id}} @$files;

    my $fh = Symbol->gensym;

    open $fh, "$CFG->{gphoto_fpath} --get-file=$range --force-overwrite 2> /dev/null |" or die $!;

    my @saved;

    while ( my $l = <$fh> ) {

        next unless $l =~ /Saving file as (.*)/;

        push @saved, $1;

    }

    close $fh;

}



sub camera_files {

# --------------------------------------------------

# Returns an array of hashrefs describing what files

# are available on the target camera

#

    my $fh = Symbol->gensym;

    open $fh, "$CFG->{gphoto_fpath} -L 2> /dev/null |" or die $!;

    my @files;

    my @headers = qw( id fname u size unit mime );

    while ( my $l = <$fh> ) {

        my @e = split /\s+/, $l;

        next unless $l =~ /^\#\d+/;

        my @e = split /\s+/, $l;

        my $rec = {};

        @$rec{@headers} = @e;

        $rec->{id} =~ s/^#//;

        push @files, $rec;

    }

    close $fh;



    return \@files;

}

---

Update: managed to get it more reliably when I invoke the script just after the camera is detected but before the second usb error is shown. Seems to be working fine as long as I get everything started in that window. W00t!

---

Update2: It's uploading! :) The script now downloads the photos to a temp directory and invokes (yet) another script that resizes via djpeg (image magick takes 4 minutes, djpeg does it in a few seconds) and uploads the result to my server. Of course, there's the little problem that it uploads /all/ my pics... but it's working! :)